Asynchronous FTP Upload

Download 32-bit Chilkat FTP2 ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

The Chilkat FTP component supports asynchronous uploads and downloads. This examples demonstrates doing an upload in a background thread. The upload is started by calling AsyncPutFileStart. While the upload is in progress, your program may do other tasks. You may periodically check the AsyncFinished property to determine when the transfer is finished. The example below provides the remainder of the details.

Dim ftp As New ChilkatFtp2

Dim success As Integer

' Any string unlocks the component for the 1st 30-days.
success = ftp.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

ftp.Hostname = "ftp.yourftpserver.com"
ftp.Username = "*myLogin6*"
ftp.Password = "*myPassword6*"

' Connect and login to the FTP server.
success = ftp.Connect()
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

' Change to the remote directory where the file will be uploaded.
success = ftp.ChangeRemoteDir("junk")
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

Dim localFilename As String
localFilename = "hamlet.xml"
Dim remoteFilename As String
remoteFilename = "hamlet.xml"

' Begin the upload in a background thread.
' Only 1 background upload or download may be active at any time.
' (per instance of an FTP object)
' To append to an existing file in the background, call
' AsyncAppendFileStart instead.
success = ftp.AsyncPutFileStart(localFilename,remoteFilename)
If (success <> 1) Then
    MsgBox ftp.LastErrorText
    Exit Sub
End If

' The application is now free to do anything else
' while the file is uploading.
' For this example, we'll simply sleep and periodically
' check to see if the transfer if finished.  While checking
' however, we'll report on the progress in both number
' of bytes tranferred and performance in bytes/second.
Do While ftp.AsyncFinished <> 1

    Text1.Text = Text1.Text & ftp.AsyncBytesSent _
         & " bytes sent" & vbCrLf
    Text1.Refresh
    Text1.Text = Text1.Text & ftp.UploadRate _
         & " bytes per second" & vbCrLf
    Text1.Refresh

    ' Sleep 1 second.
    ftp.SleepMs 1000
Loop

' Did the upload succeed?
If (ftp.AsyncSuccess = 1) Then
    MsgBox "File Uploaded!"
Else
    ' The error information for asynchronous ops
    ' is in AsyncLog as opposed to LastErrorText
    MsgBox ftp.AsyncLog
End If

ftp.Disconnect