Encrypt File to .p7m

Download Chilkat Crypt ActiveX

Visual Basic example program to encrypt a file to produce a .p7m as output. A digital certificate (public-key) is used for encrypting.

Dim crypt As New ChilkatCrypt2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    Exit Sub
End If

'  Use public-key encryption with a digital certificate:
crypt.CryptAlgorithm = "pki"

'  There are many ways to select and load a digital certificate.
'  Certs can be retrieved from the Windows registry-based
'  certificate stores, from database tables, files, etc.
'  This example will load a .cer file.
Dim cert As New ChilkatCert

success = cert.LoadFromFile("myCert.cer")
If (success <> 1) Then
    MsgBox cert.LastErrorText
    Exit Sub
End If

crypt.SetEncryptCert cert

'  The CkEncryptFile can encrypt files of any size.  The
'  encryption occurs in streaming mode, so it is not necessary
'  to hold the entire contents of the file in memory at once.
success = crypt.CkEncryptFile("dude.gif","dude.p7m")
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    Exit Sub
End If

'  To decrypt the file, you'll need the private key.
'  Also, the certificate should have already been installed
'  on the computer.  This is typically achieved by installing
'  from a .pfx file, or by importing from a certificate
'  authority's online web application.  If you are decrypting
'  from ASP, ASP.NET, or a Windows Service, you'll need to
'  import in a way that provides the calling process permission
'  to access and use the private key.  The procedure for
'  doing this is explained here:
'  http://blog.chilkatsoft.com/?p=149
' 
'  Also, there is no "SetDecryptCert" method.  The .p7m
'  contains information that allows the Chilkat component
'  to locate the certificate to be used for decryption.
'  The Chilkat Crypt component automatically searches
'  the Windows Current User certificate store and the
'  Local Machine certificate store.
success = crypt.CkDecryptFile("dude.p7m","dudeOut.gif")
If (success <> 1) Then
    MsgBox crypt.LastErrorText
    Exit Sub
End If