Add DomainKey-Signature Header to MIME / Email

Demonstrates how to add a DomainKey-Signature header field to a MIME message.

Note: The DKIM / DomainKey functionality is included with the Chilkat MIME license.

Download Chilkat FileAccess ActiveX (freeware)

Download Chilkat MIME ActiveX

'  Important: It is helpful to send the contents of the
'  dkim.LastErrorText property when requesting support.

Dim dkim As New ChilkatDkim

'  Any string automatically begins a fully-functional 30-day trial.
Dim success As Long
success = dkim.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox dkim.LastErrorText
    Exit Sub
End If

'  To create a DomainKey signature for email (i.e. MIME),
'  you'll need to provide the following:
'  (1) An RSA private key in any common file format.
'  (2) The domain name (typically the same domain
'  as the sender of an email).
'  (3) A selector for the domain name -- an arbitrary string
'  to identify the matching public key in DNS.

'  To allow an email recipient to verify the DomainKey signature via an
'  external email client supporting DomainKey or using other software,
'  you will need to create a DNS record with the selector
'  and matching public key.  This example does not provide
'  information about DomainKey DNS record creation.
'  (Chilkat does not provide an API for creating DNS records.
'  Creating the DomainKey DNS record is something you would do
'  manually.)

'  Set the domain and selector:
'  You'll need to provide your own values here..
dkim.DomainKeyDomain = "chilkatsoft.com"
dkim.DomainKeySelector = "salmon"

'  Load a private key from any common RSA private key
'  format, such as DER, PKCS8, PEM, XML, etc.
'  The LoadDomainKeyPkFile method automatically detects
'  the file format and reads it appropriately.
'  If a password is not required, you'll still need to provide
'  a password string argument, but it is ignored.
Dim password As String
password = "optionalPassword"
success = dkim.LoadDomainKeyPkFile("myPrivateKey.pem",password)
If (success <> 1) Then
    MsgBox dkim.LastErrorText
    Exit Sub
End If

'  Load a MIME file into a byte array.
Dim mimeData() As Byte
Dim fac As New CkFileAccess
mimeData = fac.ReadEntireFile("testMessage.eml")

'  Sign it.  This adds the DomainKey-Signature header and
'  returns the new MIME with DomainKey-Signature added.
Dim domainKeySignedMime() As Byte
domainKeySignedMime = dkim.AddDomainKeySignature(mimeData)

Dim facSuccess As Long
facSuccess = fac.WriteEntireFile("domainKeySigned.eml", domainKeySignedMime)
If (facSuccess = 0) Then
    MsgBox fac.LastErrorText
    Exit Sub
End If

MsgBox "Success."