Sign with .pfx to create .p7s, Verify with .cer

Download Chilkat Crypt ActiveX

Visual Basic example to sign a file using a .pfx and creating a .p7s file as output. It then uses a .cer file to verify the signature.

Dim crypt As New ChilkatCrypt2

'  Any string argument automatically begins the 30-day trial.
Dim success As Long
success = crypt.UnlockComponent("30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    Exit Sub
End If

Dim certStore As New ChilkatCertStore
success = certStore.LoadPfxFile("chilkat.pfx","myPfxPassword")
If (success <> 1) Then
    MsgBox certStore.LastErrorText
    Exit Sub
End If

Dim cert As ChilkatCert
Set cert = certStore.FindCertBySubjectCN("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
    MsgBox "Failed to find certificate"
    Exit Sub
End If

'  We can explicitly choose hash/encryption algorithms using a CSP.
Dim csp As New ChilkatCSP
csp.SetProviderMicrosoftEnhanced 
csp.SetHashAlgorithm "sha-1"

'  Tell the crypt component to use this cert and this CSP.
crypt.SetSigningCert cert
crypt.SetCSP csp

'  We can sign any type of file, creating a .p7s as output:
success = crypt.CreateP7S("hamlet.xml","hamlet.p7s")
If (success = 1) Then
    MsgBox "Signature created."
Else
    MsgBox crypt.LastErrorText
End If

'  Verify and restore the original file:
'  Use a cert from a .cer file (which only contains the public key)
Dim cert2 As New ChilkatCert
success = cert2.LoadFromFile("chilkat.cer")
If (success <> 1) Then
    MsgBox cert2.LastErrorText
    Exit Sub
End If

crypt.SetVerifyCert cert2

success = crypt.VerifyP7S("hamlet.xml","hamlet.p7s")
If (success = 1) Then
    MsgBox "Signature verified."
Else
    MsgBox crypt.LastErrorText
End If