Blowfish Encryption to Match PHP's Mcrypt Extension

Demonstrates how to match Blowfish encryption results with PHP's mcrypt extension.

Please refer to this PHP (non-Chilkat) example for PHP Blowfish Encryption. The code here matches the PHP mcrypt results on that page.

Download Chilkat Crypt ActiveX

Dim crypt As New ChilkatCrypt2

Dim success As Long
success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    Exit Sub
End If

'  Use "blowfish2" to get proper results:
crypt.CryptAlgorithm = "blowfish2"

'  CipherMode may be "ecb" or "cbc"
crypt.CipherMode = "cbc"

'  KeyLength (in bits) may be a number between 32 and 448.
'  128-bits is usually sufficient.  The KeyLength must be a
'  multiple of 8.
crypt.KeyLength = 256

'  Pad with NULL bytes (PHP pads with NULL bytes)
crypt.PaddingScheme = 3

'  EncodingMode specifies the encoding of the output for
'  encryption, and the input for decryption.
'  It may be "hex", "url", "base64", or "quoted-printable".
crypt.EncodingMode = "hex"

'  The blowfish algorithm uses a 64-bit block size,
'  therefore the IV must be 8 bytes:
Dim ivAscii As String
ivAscii = "12345678"
crypt.SetEncodedIV ivAscii,"ascii"

'  For 256-bit encryption, the key is 32 bytes:
Dim keyAscii As String
keyAscii = "1234567890123456ABCDEFGHIJKLMNOP"
crypt.SetEncodedKey keyAscii,"ascii"

Dim plainText As String
plainText = "The quick brown fox jumped over the lazy dog"

Dim cipherText As String
cipherText = crypt.EncryptStringENC(plainText)
MsgBox cipherText
'  Output should be:
'  276855ca6c0d60f7d9708210440c1072e05d078e733b34b4198d609dc2fcc2f0c30926cdef3b6d52baf6e345aa03f83e

'  Do 128-bit Blowfish encryption:
crypt.KeyLength = 128
keyAscii = "1234567890123456"
crypt.SetEncodedKey keyAscii,"ascii"

cipherText = crypt.EncryptStringENC(plainText)
MsgBox cipherText
'  Output should be:
'  d2b5abb73208aea3790621d028afcc74d8dd65fb9ea8e666444a72523f5ecca60df79a424e2c714fa6efbafcc40bdca0