Blowfish Encryption, ECB, CBC, CFB modes

Blowfish encryption. The Chilkat encryption component supports Blowfish key sizes ranging from 32-bits to 448-bits. Chilkat's blowfish implementation supports ECB (Electronic Cookbook) , CBC (Cipher-Block Chaining), and CFB (Cipher Feedback) modes.

Download Chilkat Crypt ActiveX

Dim crypt As New ChilkatCrypt2

Dim success As Long
success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    Exit Sub
End If

'  Attention: use "blowfish2" for the algorithm name:
crypt.CryptAlgorithm = "blowfish2"

'  CipherMode may be "ecb", "cbc", or "cfb"
crypt.CipherMode = "cbc"

'  KeyLength (in bits) may be a number between 32 and 448.
'  128-bits is usually sufficient.  The KeyLength must be a
'  multiple of 8.
crypt.KeyLength = 128

'  The padding scheme determines the contents of the bytes
'  that are added to pad the result to a multiple of the
'  encryption algorithm's block size.  Blowfish has a block
'  size of 8 bytes, so encrypted output is always
'  a multiple of 8.
crypt.PaddingScheme = 0

'  EncodingMode specifies the encoding of the output for
'  encryption, and the input for decryption.
'  It may be "hex", "url", "base64", or "quoted-printable".
crypt.EncodingMode = "hex"

'  An initialization vector is required if using CBC or CFB modes.
'  ECB mode does not use an IV.
'  The length of the IV is equal to the algorithm's block size.
'  It is NOT equal to the length of the key.
Dim ivHex As String
ivHex = "0001020304050607"
crypt.SetEncodedIV ivHex,"hex"

'  The secret key must equal the size of the key.  For
'  256-bit encryption, the binary secret key is 32 bytes.
'  For 128-bit encryption, the binary secret key is 16 bytes.
Dim keyHex As String
keyHex = "000102030405060708090A0B0C0D0E0F"
crypt.SetEncodedKey keyHex,"hex"

'  Encrypt a string...
'  The input string is 44 ANSI characters (i.e. 44 bytes), so
'  the output should be 48 bytes (a multiple of 8).
'  Because the output is a hex string, it should
'  be 96 characters long (2 chars per byte).
Dim encStr As String
encStr = crypt.EncryptStringENC("The quick brown fox jumps over the lazy dog.")
MsgBox encStr

'  Now decrypt:
Dim decStr As String
decStr = crypt.DecryptStringENC(encStr)
MsgBox decStr