Amazon AIM Upload Inventory

Demonstrates how to upload an inventory management file using the Amazon Inventory Management (AIM) API.

Download Chilkat HTTP ActiveX

Dim req As New ChilkatHttpRequest
Dim http As New ChilkatHttp

Dim success As Long

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox http.LastErrorText
    Exit Sub
End If

'  The CookieDir may be set to "memory" to keep an in-memory cache of cookies.
'  Alternatively, you may set it to a directory, such as "c:/temp/cookies".  If you do that,
'  you can visually browse the cookies which will appear as XML files in the CookieDir.
http.CookieDir = "memory"

'  Tell the HTTP component to save any cookies received.  Also tell the component to
'  re-send cookies with subsequent GETs and POSTs.
http.SendCookies = 1
http.SaveCookies = 1

'  Build an HTTP upload request:
req.UseUpload 

'  The path may be one of these 3 choices:
'  /exec/panama/seller-admin/catalog-upload/add-modify-delete
'  /exec/panama/seller-admin/catalog-upload/modify-only
'  /exec/panama/seller-admin/catalog-upload/purge-replace
req.Path = "/exec/panama/seller-admin/catalog-upload/add-modify-delete"

'  Load the inventory file into the HTTPS request:
success = req.AddFileForUpload("myInventory","myInventory.txt")
If (success <> 1) Then
    MsgBox req.LastErrorText
    Exit Sub
End If

'  Setting your login/password causes Chilkat to automatically add the Authorization header:
http.Login = "YourLoginEmailAddress"
http.Password = "YourPassword"

' call req.AddHeader("BatchID", "Y");
req.AddHeader "FileFormat","TabDelimited"
req.AddHeader "UploadFor","MarketplaceOnly"

'  Send the HTTP POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTP response is received.
Dim domain As String
Dim port As Long
Dim ssl As Long
domain = "merchant-query.amazon.com"
port = 443
ssl = 1

Dim resp As ChilkatHttpResponse
Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    Text1.Text = Text1.Text & http.LastErrorText & vbCrLf
Else
    '  Display the XML returned.
    Text1.Text = Text1.Text & resp.BodyStr & vbCrLf
End If