Encrypting/decrypting a data stream.

Download Chilkat Crypt ActiveX

This example demonstrates how to encrypt (using a symmetric encryption algorithm such as AES, Blowfish, RC2, 3DES, etc) a large amount of data. The data is passed in chunks to one of the encrypt methods: EncryptBytes, EncryptString, EncryptBytesENC, or EncryptStringENC. (The method name indicates the type of input (string or byte array) and the return type (encoded string or byte array). The FirstChunk and LastChunk properties are used to indicate whether a chunk is the first, middle, or last in a stream to be encrypted. By default, both FirstChunk and LastChunk equal 1 -- meaning that the data passed is the entire amount.

Note: You may feed the data in chunks that are smaller than the block size of the encryption algorithm (AES and Twofish have a block size of 16 bytes. DES, 3DES, Blowfish, and RC2 have a block size of 8 bytes. ARC4 is a streaming encryption algorithm and does not have a block size, but technically you can think of it as having a block size of 1 byte.) The Chilkat Crypt component will buffer the data as required. If an amount of data smaller than the block size is passed such that the entire amount is buffered, then an empty string is returned. The buffered data will be added to the data passed in subsequent calls. When the final data chunk is passed, it is padded to the encryption algorithm's block size (according to the PaddingScheme property) and the encryption is complete. Decrypting in chunks is identical to encrypting in chunks. Note: This example uses new features available in the pre-release, or any official new version released after 17-October-2007.

Dim crypt As New ChilkatCrypt2

Dim success As Long
success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    MsgBox "Crypt component unlock failed"
    Exit Sub
End If

'  This example works with the following algorithms supported
'  by Chilkat: AES, Blowfish, Twofish, DES, 3DES, RC2, ARC4,
'  and potentially others implemented after the time this
'  example was written.
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

crypt.SetEncodedKey "000102030405060708090A0B0C0D0E0F","hex"

crypt.EncodingMode = "hex"
Dim txt1 As String
txt1 = "The quick brown fox jumped over the lazy dog." & vbCrLf
Dim txt2 As String
txt2 = "-" & vbCrLf
Dim txt3 As String
txt3 = "Done." & vbCrLf

'  Encrypt the 1st chunk:
'  (don't worry about feeding the data to the encryptor in
'  exact multiples of the encryption algorithm's block size.
'  The Chilkat Crypt component buffers the data internally.)
crypt.FirstChunk = 1
crypt.LastChunk = 0
Dim encryptedText As String
encryptedText = crypt.EncryptStringENC(txt1)

'  Encrypt the 2nd chunk
crypt.FirstChunk = 0
crypt.LastChunk = 0
encryptedText = encryptedText + crypt.EncryptStringENC(txt2)

'  Now encrypt N more chunks...
'  Remember -- we're doing this in CBC mode, so each call
'  to the encrypt method depends on the state from previous
'  calls...
crypt.FirstChunk = 0
crypt.LastChunk = 0
Dim i As Long
For i = 0 To 4
    encryptedText = encryptedText + crypt.EncryptStringENC(txt1)
    encryptedText = encryptedText + crypt.EncryptStringENC(txt2)
Next

'  Now encrypt the last chunk:
crypt.FirstChunk = 0
crypt.LastChunk = 1
encryptedText = encryptedText + crypt.EncryptStringENC(txt3)

Text1.Text = Text1.Text & encryptedText & vbCrLf
Text1.Refresh

'  Now decrypt in one call.
'  (The data we're decrypting is both the first AND last chunk.)
crypt.FirstChunk = 1
crypt.LastChunk = 1
Dim decryptedText As String
decryptedText = crypt.DecryptStringENC(encryptedText)

Text1.Text = Text1.Text & decryptedText & vbCrLf
Text1.Refresh

'  Note: You may decrypt in N chunks by setting the FirstChunk
'  and LastChunk properties prior to calling the Decrypt* methods.