SSL Server Example

Demonstrates how to create an SSL socket for accepting connections. This example is *very* simple in that it will create an SSL socket for accepting a single connection. It will read a message from the client, send a reply, and exit.

Download Chilkat Socket ActiveX

LOCAL loListenSslSocket
LOCAL lnSuccess
LOCAL loCertStore
LOCAL loCert
LOCAL lnMyPort
LOCAL lnBackLog
LOCAL loClientSock
LOCAL lnMaxWaitMillisec
LOCAL lcReceivedMsg

loListenSslSocket = CreateObject('Chilkat.Socket')

*  Any string automatically begins a fully-functional 30-day trial.

lnSuccess = loListenSslSocket.UnlockComponent("Anything for 30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("Failed to unlock component")
    QUIT
ENDIF

*  An SSL server needs a digital certificate.  This example loads it from a PFX file.

*  Create an instance of a certificate store object, load a PFX file,
*  locate the certificate we need, and use it.
*  (a PFX file may contain more than one certificate.)
loCertStore = CreateObject('Chilkat.CertStore')
*  The 1st argument is the filename, the 2nd arg is the
*  PFX file's password:
lnSuccess = loCertStore.LoadPfxFile("chilkat.pfx","test")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loCertStore.LastErrorText)
    QUIT
ENDIF

*  Find the certificate to be used for SSL:

loCert = loCertStore.FindCertBySubject("Chilkat Software, Inc.")
IF (loCert = NULL ) THEN
    =MESSAGEBOX(loCertStore.LastErrorText)
    QUIT
ENDIF

*  Use the certificate:
lnSuccess = loListenSslSocket.InitSslServer(loCert)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loListenSslSocket.LastErrorText)
    QUIT
ENDIF

*  Bind and listen on a port:

lnMyPort = 8123
*  Allow for a max of 5 queued connect requests.

lnBackLog = 5
lnSuccess = loListenSslSocket.BindAndListen(lnMyPort,lnBackLog)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loListenSslSocket.LastErrorText)
    QUIT
ENDIF

*  Accept a single client connection:

lnMaxWaitMillisec = 20000
loClientSock = loListenSslSocket.AcceptNextConnection(lnMaxWaitMillisec)
IF (loClientSock = NULL ) THEN
    =MESSAGEBOX(loListenSslSocket.LastErrorText)
    QUIT
ENDIF

*  The client (in this example) is going to send a "Hello Server! -EOM-"
*  message.  Read it:

lcReceivedMsg = loClientSock.ReceiveUntilMatch("-EOM-")
IF (lcReceivedMsg = NULL ) THEN
    =MESSAGEBOX(loClientSock.LastErrorText)
    QUIT
ENDIF

=MESSAGEBOX(lcReceivedMsg)

*  Send a "Hello Client! -EOM-" message:
lnSuccess = loClientSock.SendString("Hello Client! -EOM-")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loClientSock.LastErrorText)
    QUIT
ENDIF

*  Close the connection with the client
*  Wait a max of 20 seconds (20000 millsec)
loClientSock.Close(20000)