Send S/MIME Encrypted Email

Send encrypted email using the digital certificate of the recipient. To successfully encrypt, the recipient's certificate must be installed or available from a .cer file or elsewhere (such as LDAP, a database, etc.). Only the public key is required to encrypt an email. The private key is not necessary. (The private key is necessary for decryption. Thus, when an encrypted email is sent, only the recipient may decrypt because only the recipient holds the private key.)

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

LOCAL loMailman
LOCAL lnSuccess
LOCAL loEmail

*  The mailman object is used for sending and receiving email.
loMailman = CreateObject('Chilkat.MailMan2')

*  Any string argument automatically begins the 30-day trial.

lnSuccess = loMailman.UnlockComponent("30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("Component unlock failed")
    QUIT
ENDIF

*  Set the SMTP server.
loMailman.SmtpHost = "smtp.comcast.net"

*  Create a new email object
loEmail = CreateObject('Chilkat.Email2')

loEmail.Subject = "This email is encrypted"
loEmail.Body = "This is a digitally encrypted mail"
loEmail.From = "Chilkat Support <support@chilkatsoft.com>"
loEmail.AddTo("TagTooga","admin@tagtooga.com")

*  In this example, we've already installed the certificate for "admin@tagtooga.com"
*  in the current user's personal certificate store.
*  If the email.SendEncrypted property is set, Chilkat will
*  automatically search for and use the first non-expired certificate
*  matching the recipient's email address.  Chilkat searches
*  the Current User's Personal certificate store, as well
*  as the Local Machine's Personal certificate store.
*  Run certmgr.msc to view the certs in the Current User's
*  certificate store.
loEmail.SendEncrypted = 1

lnSuccess = loMailman.SendEmail(loEmail)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loMailman.LastErrorText)
ELSE
    =MESSAGEBOX("Mail Sent!")
ENDIF