Send Email with Inline Attachment

Download Chilkat Email ActiveX

Create an send an email with an inline attachment.

LOCAL loMailman
LOCAL lnSuccess
LOCAL loEmail
LOCAL lcContentType

*  The mailman object is used for sending and receiving email.
loMailman = CreateObject('Chilkat.MailMan2')

*  Any string argument automatically begins the 30-day trial.

lnSuccess = loMailman.UnlockComponent("30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("Component unlock failed")
    QUIT
ENDIF

*  Set the SMTP server.
loMailman.SmtpHost = "smtp.chilkatsoft.com"

*  You may need a login/password.  In many cases,
*  authentication is not required when sending local email
*  (i.e. to email addresses having the same domain as the
*  SMTP server), but is required when sending to non-local
*  recipients.
loMailman.SmtpUsername = "myLogin"
loMailman.SmtpPassword = "myPassword"

*  Create a new email object
loEmail = CreateObject('Chilkat.Email2')

loEmail.Subject = "This is a test"
loEmail.Body = "This is a test"
loEmail.From = "Chilkat Support <support@chilkatsoft.com>"
loEmail.AddTo("Chilkat Admin","admin@chilkatsoft.com")

*  Add any number of attachments:

lcContentType = loEmail.AddFileAttachment("c:/temp/dude.gif")
IF (lcContentType = NULL ) THEN
    =MESSAGEBOX(loEmail.LastErrorText)
    QUIT
ENDIF

*  Update the content-disposition header field for the attachment
*  so that it's sent inline:
*  AddAttachmentHeader replaces the header field if it already
*  exists.
loEmail.AddAttachmentHeader(0,"content-disposition",[inline; filename="dude.gif"])

lnSuccess = loMailman.SendEmail(loEmail)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loMailman.LastErrorText)
ELSE
    =MESSAGEBOX("Mail Sent!")
ENDIF