RSA Signature with Certificate's Private Key from PFX

Demonstrates how to use a certificate's private key from a PFX file to create an RSA signature.

Download 32-bit Chilkat RSA ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

LOCAL lnSuccess
LOCAL loCertStore
LOCAL loCert
LOCAL loPkey
LOCAL lcPkeyXml
LOCAL loRsa
LOCAL lcStrData
LOCAL lcHexSig



*  Create an instance of a certificate store object, load a PFX file,
*  locate the certificate we need, and use it for signing.
*  (a PFX file may contain more than one certificate.)
loCertStore = CreateObject('Chilkat.CertStore')

*  The 1st argument is the filename, the 2nd arg is the
*  PFX file's password:
lnSuccess = loCertStore.LoadPfxFile("chilkat.pfx","test")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loCertStore.LastErrorText)
    QUIT
ENDIF

loCert = loCertStore.FindCertBySubject("Chilkat Software, Inc.")
IF (loCert = NULL ) THEN
    =MESSAGEBOX(loCertStore.LastErrorText)
    QUIT
ENDIF

loPkey = loCert.ExportPrivateKey()
IF (loPkey = NULL ) THEN
    =MESSAGEBOX(loCert.LastErrorText)
    QUIT
ENDIF

*  Get the private key in XML format:
lcPkeyXml = loPkey.GetXml()
RELEASE loPkey

loRsa = CreateObject('Chilkat.Rsa')

*  Any string argument automatically begins the 30-day trial.

lnSuccess = loRsa.UnlockComponent("30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("RSA component unlock failed")
    QUIT
ENDIF

*  Import the private key into the RSA component:
lnSuccess = loRsa.ImportPrivateKey(lcPkeyXml)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loRsa.LastErrorText)
    QUIT
ENDIF

*  This example will sign a string, and receive the signature
*  in a hex-encoded string.  Therefore, set the encoding mode
*  to "hex":
loRsa.EncodingMode = "hex"

*  If some other non-Chilkat application or web service is going to be verifying
*  the signature, it is important to match the byte-ordering.
*  The LittleEndian property may be set to 1
*  for little-endian byte ordering,
*  or 0  for big-endian byte ordering.
*  Microsoft apps typically use little-endian, while
*  OpenSSL and other services (such as Amazon CloudFront)
*  use big-endian.
loRsa.LittleEndian = 0

lcStrData = "This is the string to be signed."

*  Sign the string using the sha-1 hash algorithm.
*  Other valid choices are "md2" and "md5".

lcHexSig = loRsa.SignStringENC(lcStrData,"sha-1")

? lcHexSig

=MESSAGEBOX("Success!")