Duplicating OpenSSL rsautl (creating RSA signatures)

Demonstrates how to duplicate OpenSSL rsautil RSA signatures.

The Chilkat RSA component's methods for creating RSA signatures (SignBytes, SignBytesENC, SignString, and SignStringENC) are very different from OpenSSL's rsautl command. First, we'll explain what Chilkat's signing methods do, and then what OpenSSL's rsautl does. New signing methods have been added to Chilkat RSA to duplicate OpenSSL rsautl: OpenSslSignBytes, OpenSslSignBytesENC, OpenSslSignString, and OpenSslSignStringENC.

Here's what Chilkat's RSA Sign* methods do:
(Note: Chilkat RSA's Sign* methods generate signatures according to RSA Laboratories' "PKCS #1 v2.0: RSA Cryptography Standard".)

1. Input data is hashed using the hashing algorithm specified.
2. The hash is padded using either PKCS1 v1.5 or PKCS1 PSS padding. PKCS v1.5 involves encoding to ASN.1 before padding.
3. The padded hash is finally RSA signed (i.e. modular exponentiation) and the signature is returned.

OpenSSL rsautl is very different. Here's what it does:

1. The input data is not hashed. It must be a small enough amount of data such that it can be padded and signed. PKCS v1.5 padding is always used. The data is not ASN.1 encoded before padding.
2. The PKCS v1.5 padded data is RSA signed and the signature is returned.

Download Chilkat RSA ActiveX

LOCAL lnSuccess
LOCAL loPkey
LOCAL lcPkeyXml
LOCAL loRsa
LOCAL lcStrData
LOCAL lcHexSig
LOCAL loPubkey
LOCAL lcPubkeyXml
LOCAL loRsa2
LOCAL lcOriginalData



loPkey = CreateObject('Chilkat.PrivateKey')

*  Load the private key from an RSA PEM file:
lnSuccess = loPkey.LoadPemFile("private.pem")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loPkey.LastErrorText)
    QUIT
ENDIF

*  Get the private key in XML format:
lcPkeyXml = loPkey.GetXml()

loRsa = CreateObject('Chilkat.Rsa')

*  Any string argument automatically begins the 30-day trial.

lnSuccess = loRsa.UnlockComponent("30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("RSA component unlock failed")
    QUIT
ENDIF

*  Import the private key into the RSA component:
lnSuccess = loRsa.ImportPrivateKey(lcPkeyXml)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loRsa.LastErrorText)
    QUIT
ENDIF

*  This example will sign a string, and receive the signature
*  in a hex-encoded string.  Therefore, set the encoding mode
*  to "hex":
loRsa.EncodingMode = "hex"

lcStrData = "secret"

*  Create an OpenSSL style signature:

lcHexSig = loRsa.OpenSslSignStringENC(lcStrData)

? lcHexSig

*  Recover the data using the corresponding public key:
loPubkey = CreateObject('Chilkat.PublicKey')

*  Load the public key from a PEM file:
lnSuccess = loPubkey.LoadOpenSslPemFile("public.pem")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loPubkey.LastErrorText)
    QUIT
ENDIF

*  Get the public key in XML format:
lcPubkeyXml = loPubkey.GetXml()

loRsa2 = CreateObject('Chilkat.Rsa')

*  Import the public key into the RSA component:
lnSuccess = loRsa2.ImportPublicKey(lcPubkeyXml)
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loRsa2.LastErrorText)
    QUIT
ENDIF

loRsa2.EncodingMode = "hex"

*  Recover the original data.

lcOriginalData = loRsa2.OpenSslVerifyStringENC(lcHexSig)

? lcOriginalData