POP3: Download Most Recent Email (method 2)

Download Chilkat Email ActiveX

How to ready the N most recent email from a POP3 server.

The POP3 protocol does not provide the ability to request the most recent email, nor does it provide the ability to download email based on read/unread status or any other criteria. The design principle behind POP3 is that it is a temporary holding store for incoming email and email clients or other applications will transfer email from the POP3 server to a local persistent store where it will be managed. Therefore, POP3 does not provide sophisticated functionality (as opposed to IMAP which has the opposite design philosophy: that email is maintained and organized on the server).

This example shows one possible way to retrieve the N most recent emails from a POP3 server. It downloads the complete list of UIDLs and then downloads the last N into a bundle object. It assumes that the UIDLs will be returned by the POP3 server ordered by date such that the 1st email in the UIDL list is the oldest, and the last email is the newest.

LOCAL loMailman
LOCAL lnSuccess
LOCAL loSaUidls
LOCAL i
LOCAL n
LOCAL lnStartIdx
LOCAL loSaUidls2
LOCAL loBundle
LOCAL loEmail

*  The mailman object is used for receiving (POP3)
*  and sending (SMTP) email.
loMailman = CreateObject('Chilkat.MailMan2')

*  Any string argument automatically begins the 30-day trial.

lnSuccess = loMailman.UnlockComponent("30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("Component unlock failed")
    QUIT
ENDIF

*  Set the POP3 server's hostname
loMailman.MailHost = "mail.chilkatsoft.com"

*  Set the POP3 login/password.
loMailman.PopUsername = "admin@chilkatsoft.com"
loMailman.PopPassword = "****"

*  Get the complete list of UIDLs
loSaUidls = loMailman.GetUidls()

IF (loSaUidls = NULL ) THEN
    =MESSAGEBOX(loMailman.LastErrorText)
    QUIT
ENDIF

*  Get the 10 most recent UIDLs
*  The 1st email is the oldest, the last email is the newest
*  (usually)

n = loSaUidls.Count
IF (n > 10) THEN
    lnStartIdx = n - 10
ELSE
    lnStartIdx = 0
ENDIF

loSaUidls2 = CreateObject('Chilkat.CkStringArray')
FOR i = lnStartIdx TO n - 1
    loSaUidls2.Append(loSaUidls.GetString(i))
NEXT

RELEASE loSaUidls

*  Download in full the 10 most recent emails:

loBundle = loMailman.FetchMultiple(loSaUidls2)
IF (loBundle = NULL ) THEN
    =MESSAGEBOX(loMailman.LastErrorText)
    QUIT
ENDIF

FOR i = 0 TO loBundle.MessageCount - 1
    loEmail = loBundle.GetEmail(i)
    ? loEmail.From
    ? loEmail.Subject
    ? "----"
    RELEASE loEmail
NEXT