Read IMAP Email Headers

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

Call FetchHeaders to download only the email headers.

LOCAL loImap
LOCAL lnSuccess
LOCAL loMessageSet
LOCAL lnFetchUids
LOCAL loBundle
LOCAL i
LOCAL loEmail
LOCAL j
LOCAL lcName
LOCAL lcAddr
LOCAL lnNumAttach
LOCAL lnAttachSize

loImap = CreateObject('Chilkat.Imap')

*  Anything unlocks the component and begins a fully-functional 30-day trial.
lnSuccess = loImap.UnlockComponent("Anything for 30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loImap.LastErrorText)
    QUIT
ENDIF

*  Connect to an IMAP server.
lnSuccess = loImap.Connect("mail.chilkatsoft.com")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loImap.LastErrorText)
    QUIT
ENDIF

*  Login
lnSuccess = loImap.Login("****","****")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loImap.LastErrorText)
    QUIT
ENDIF

*  Select an IMAP mailbox
lnSuccess = loImap.SelectMailbox("Inbox")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX(loImap.LastErrorText)
    QUIT
ENDIF

*  We can choose to fetch UIDs or sequence numbers.

lnFetchUids = 1
*  Get the message IDs of all the emails in the mailbox
loMessageSet = loImap.Search("ALL",lnFetchUids)
IF (loMessageSet = NULL ) THEN
    =MESSAGEBOX(loImap.LastErrorText)
    QUIT
ENDIF

*  When downloading headers, each email object contains
*  (obviously) the headers, but the body will be missing.
*  Also, attachments will not be included.  However, it is
*  possible to get information about the attachments
*  as well as the complete size of the email.

loBundle = loImap.FetchHeaders(loMessageSet)
IF (loBundle = NULL ) THEN
    RELEASE loMessageSet
    =MESSAGEBOX(loImap.LastErrorText)
    QUIT
ENDIF

*  Loop over the email objects and display information
*  about each:

FOR i = 0 TO loBundle.MessageCount - 1

    loEmail = loBundle.GetEmail(i)

    *  Display the From and Subject
    ? loEmail.From
    ? loEmail.Subject

    *  Display the recipients:

    FOR j = 0 TO loEmail.NumTo - 1
        lcName = loEmail.GetToName(j)
        lcAddr = loEmail.GetToAddr(j)
        ? lcName + ", " + lcAddr
    NEXT
    FOR j = 0 TO loEmail.NumCC - 1
        lcName = loEmail.GetCcName(j)
        lcAddr = loEmail.GetCcAddr(j)
        ? lcName + ", " + lcAddr
    NEXT

    *  Show the total size of the email, including body and attachments:
    ? loEmail.Size

    *  When a full email is downloaded, we would use the
    *  email.NumAttachments property in conjunction with the
    *  email.GetMailAttach* methods.
    *  However, when an email object contains only the header,
    *  we need to access the attachment info differently:

    lnNumAttach = loImap.GetMailNumAttach(loEmail)
    FOR j = 0 TO lnNumAttach - 1
        ? loImap.GetMailAttachFilename(loEmail,j)

        lnAttachSize = loImap.GetMailAttachSize(loEmail,j)
        ? "    size = " + STR(lnAttachSize) + " bytes"
    NEXT

    ? "--"
    RELEASE loEmail
NEXT

*  Disconnect from the IMAP server.
loImap.Disconnect()

RELEASE loMessageSet
RELEASE loBundle