56-bit DES Encryption, ECB, CBC modes

56-bit DES encryption. The Chilkat encryption component supports DES in both ECB (Electronic Cookbook) and CBC (Cipher-Block Chaining) cipher modes.

Download Chilkat Crypt ActiveX

LOCAL loCrypt
LOCAL lnSuccess
LOCAL lcIvHex
LOCAL lcKeyHex
LOCAL lcEncStr
LOCAL lcDecStr

loCrypt = CreateObject('Chilkat.Crypt2')

lnSuccess = loCrypt.UnlockComponent("Anything for 30-day trial")
IF (lnSuccess <> 1) THEN
    =MESSAGEBOX("Crypt component unlock failed")
    QUIT
ENDIF

*  Specify DES for the encryption algorithm:
loCrypt.CryptAlgorithm = "des"

*  CipherMode may be "ecb" or "cbc"
loCrypt.CipherMode = "cbc"

*  KeyLength must be 64.  DES is technically 56-bits;
*  the most-significant bit of each key byte is a parity bit,
*  so we must indicate a KeyLength of 64, which includes
*  the parity bits.
loCrypt.KeyLength = 64

*  The padding scheme determines the contents of the bytes
*  that are added to pad the result to a multiple of the
*  encryption algorithm's block size.  DES has a block
*  size of 8 bytes, so encrypted output is always
*  a multiple of 8.
loCrypt.PaddingScheme = 0

*  EncodingMode specifies the encoding of the output for
*  encryption, and the input for decryption.
*  It may be "hex", "url", "base64", or "quoted-printable".
loCrypt.EncodingMode = "hex"

*  An initialization vector is required if using CBC or CFB modes.
*  ECB mode does not use an IV.
*  The length of the IV is equal to the algorithm's block size.
*  It is NOT equal to the length of the key.

lcIvHex = "0001020304050607"
loCrypt.SetEncodedIV(lcIvHex,"hex")

*  The secret key must equal the size of the key.  For
*  DES, the key must be 8 bytes (i.e. 64-bits).

lcKeyHex = "0001020304050607"
loCrypt.SetEncodedKey(lcKeyHex,"hex")

*  Encrypt a string...
*  The input string is 44 ANSI characters (i.e. 44 bytes), so
*  the output should be 48 bytes (a multiple of 8).
*  Because the output is a hex string, it should
*  be 96 characters long (2 chars per byte).

lcEncStr = loCrypt.EncryptStringENC("The quick brown fox jumps over the lazy dog.")
=MESSAGEBOX(lcEncStr)

*  Now decrypt:

lcDecStr = loCrypt.DecryptStringENC(lcEncStr)
=MESSAGEBOX(lcDecStr)