Send Already-Signed MIME w/ SendMime
Demonstrates how to use SendMime to send an already-signed MIME message.
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' The mailman object is used for sending and receiving email.
set mailman = Server.CreateObject("Chilkat_9_5_0.MailMan")
' Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
Response.Write "Component unlock failed" & "<br>"
End If
' Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"
' Create a new email object
set email = Server.CreateObject("Chilkat_9_5_0.Email")
email.Subject = "This email is signed"
email.Body = "This is a digitally signed mail"
email.From = "Chilkat Admin <admin@chilkatsoft.com>"
email.AddTo "Chilkat Support","support@chilkatsoft.com"
' Indicate that the email should be sent signed.
email.SendSigned = 1
' Create an instance of a certificate store object, load a PFX file,
' locate the certificate we need, and use it for signing.
' (a PFX file may contain more than one certificate.)
set certStore = Server.CreateObject("Chilkat_9_5_0.CertStore")
' The 1st argument is the filename, the 2nd arg is the
' PFX file's password:
success = certStore.LoadPfxFile("chilkat.pfx","myPassword")
If (success <> 1) Then
Response.Write certStore.LastErrorText & "<br>"
End If
Set cert = certStore.FindCertBySubject("Chilkat Software, Inc.")
If (cert Is Nothing ) Then
Response.Write certStore.LastErrorText & "<br>"
End If
' This example will use the cert from the certStore...
email.SetSigningCert cert
' Render the email to signed-MIME. This is where the private
' key is accessed and the signing happens.
signedMime = mailman.RenderToMime(email)
' Now send the already-signed MIME:
fromAddr = "admin@chilkatsoft.com"
recipients = "support@chilkatsoft.com, matt@chilkatsoft.com"
success = mailman.SendMime(fromAddr,recipients,signedMime)
If (success <> 1) Then
Response.Write mailman.LastErrorText & "<br>"
Else
' The LastErrorText property provides information
' even when successful.
Response.Write mailman.LastErrorText & "<br>"
Response.Write "Mail Sent!" & "<br>"
End If
%>
</body>
</html>
|
