Send a Simple HTML Email

Demonstrates how to send a simple HTML email (i.e. with no images, style sheets, etc.).

Download Chilkat Email ActiveX

Download 32-bit Chilkat IMAP ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
'  The mailman object is used for sending and receiving email.
set mailman = Server.CreateObject("Chilkat.MailMan2")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( mailman.LastErrorText) & "</pre>"

End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"

'  Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"

'  Create a new email object
set email = Server.CreateObject("Chilkat.Email2")

email.Subject = "This is a test"
email.SetHtmlBody "<html><body><p>This is <b>bold text</b>, this is a <a href=""http://www.chilkatsoft.com/"">hyperlink</a></p></body></html>"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"

'  Call SendEmail to connect to the SMTP server and send.
'  The connection (i.e. session) to the SMTP server remains
'  open so that subsequent SendEmail calls may use the
'  same connection.
success = mailman.SendEmail(email)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode(mailman.LastErrorText) & "</pre>"

End If

'  Some SMTP servers do not actually send the email until
'  the connection is closed.  In these cases, it is necessary to
'  call CloseSmtpConnection for the mail to be  sent.
'  Most SMTP servers send the email immediately, and it is
'  not required to close the connection.  We'll close it here
'  for the example:
success = mailman.CloseSmtpConnection()
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode("Connection to SMTP server not closed cleanly.") & "</pre>"
End If

Response.Write "<pre>" & Server.HTMLEncode("Mail Sent!") & "</pre>"
%>
</body>
</html>