Amazon S3 - List Buckets

Demonstrates how to send a GET request to the Amazon S3 service to list buckets.

Download Chilkat Crypt ActiveX

Download Chilkat HTTP ActiveX

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set http = Server.CreateObject("Chilkat.Http")
success = http.UnlockComponent("Anything for 30-day trial.")
If (success <> 1) Then
    '  Unlock failed.
    Response.Write http.LastErrorText & "<br>"

End If

'  The HTTP component now includes a method to generate
'  the current date/time in RFC 2616 compliant format.
'  Note: The GenTimeStamp method is available as a pre-release (as of 18-June-2008).
'  It will become available in the next new version dated after
'  18-June-2008.
curDateTime = http.GenTimeStamp()

Response.Write curDateTime & "<br>"

'  The GET operation on the Service endpoint (s3.amazonaws.com) returns a list of all of the buckets owned by the authenticated sender of the request.
strToSign = "GET" & vbLf & vbLf & vbLf & curDateTime & vbLf & "/"

set crypt = Server.CreateObject("Chilkat.Crypt2")

success = crypt.UnlockComponent("Anything for 30-day trial.")
If (success <> 1) Then
    Response.Write crypt.LastErrorText & "<br>"

End If

'  We want SHA1 for the HMAC hash algorithm:
crypt.HashAlgorithm = "sha1"

'  These must be changed for your account:
AWSAccessKeyId = "0PN5J17HBGZHT7JJ3X82"
AWSSecretAccessKey = "uV3F3YluFJax1cknvbcGwgjvx4QpvB+leU8dUj2o"

'  Set the HMAC secret key:
crypt.SetHmacKeyString AWSSecretAccessKey

'  By setting the charset = "utf-8", the string will be converted
'  to utf-8 (internal to the Chilkat component) prior to signing:
crypt.Charset = "utf-8"

'  Indicate that Base64 output is desired:
crypt.EncodingMode = "base64"

signature = crypt.HmacStringENC(strToSign)

authValue = "AWS " & AWSAccessKeyId & ":" & signature

http.SetRequestHeader "Authorization",authValue
http.SetRequestHeader "Date",curDateTime

xmlResponse = http.QuickGetStr("http://s3.amazonaws.com/")
If (xmlResponse = vbNullString ) Then
    '  Failed.  Show the last request header, response header,
    '  and response body.
    Response.Write Server.HTMLEncode( http.LastHeader) & "<br>"
    Response.Write Server.HTMLEncode( "---") & "<br>"
    Response.Write Server.HTMLEncode( http.LastResponseHeader) & "<br>"
    Response.Write Server.HTMLEncode( "---") & "<br>"
    Response.Write Server.HTMLEncode( http.LastErrorText) & "<br>"
Else
    '  Success, show the XML response:
    Response.Write Server.HTMLEncode( xmlResponse) & "<br>"
End If

%>
</body>
</html>