Generate RSA Key and Sign a String

Demonstrates how to generate a new RSA public/private key pair and use it to generate a signature for a string. The (binary) digital signature is returned as a hexidecimalized string.

Download Chilkat RSA Public-Key Encryption ActiveX

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set rsa = Server.CreateObject("Chilkat.Rsa")

'  Any string argument automatically begins the 30-day trial.
success = rsa.UnlockComponent("30-day trial")
If (success <> 1) Then
    Response.Write "RSA component unlock failed" & "<br>"

End If

'  Generate a 1024-bit RSA key pair.
rsa.GenerateKey 1024

'  This example will sign a string, and receive the signature
'  in a hex-encoded string.  Therefore, set the encoding mode
'  to "hex":
rsa.EncodingMode = "hex"

strData = "This is the string to be signed."

'  Sign the string using the  md5 hash algorithm.
'  Other valid choices are "md2" and "sha-1".
hexSig = rsa.SignStringENC(strData,"md5")

Response.Write Server.HTMLEncode( hexSig) & "<br>"
Response.Write Server.HTMLEncode( rsa.LastErrorText) & "<br>"

'  Now verify the signature:
success = rsa.VerifyStringENC(strData,"md5",hexSig)
If (success = 1) Then
    Response.Write "Signature verified!" & "<br>"
Else
    Response.Write Server.HTMLEncode( rsa.LastErrorText) & "<br>"
End If

'  Try it with an invalid signature:
success = rsa.VerifyStringENC(strData,"md5","not a valid sig")
If (success = 1) Then
    Response.Write "Signature verified!" & "<br>"
Else
    Response.Write Server.HTMLEncode( rsa.LastErrorText) & "<br>"
End If

'  Try it with invalid data:
success = rsa.VerifyStringENC("Not the original data","md5",hexSig)
If (success = 1) Then
    Response.Write "Signature verified!" & "<br>"
Else
    Response.Write Server.HTMLEncode( rsa.LastErrorText) & "<br>"
End If

'  Try it with the wrong hash algorithm:
success = rsa.VerifyStringENC(strData,"sha-1",hexSig)
If (success = 1) Then
    Response.Write "Signature verified!" & "<br>"
Else
    Response.Write Server.HTMLEncode( rsa.LastErrorText) & "<br>"
End If

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com