Create Complex Email

This is an example showing how to create an email that has file attachments, contains both plain-text and HTML alternative bodies, and has embedded images within the HTML. The email is saved to a .eml file, which is a text file and can be viewed in any text editor. EML is nothing more than the MIME source of an email. In this example, you'll see that the MIME is structured in three layers of multipart content types. The outermost layer is multipart/mixed. This is typically where you'll find file attachments and attached messages. Underneath the multipart/mixed is a multipart/related envelope. Within this you'll find the "related" items -- which are the items belonging to the HTML body (images and style sheets). Underneath the multipart/related you'll find the multipart/alternative, and this contains the text/plain and text/html alternative bodies.

Download Chilkat Email ActiveX for POP3 / SMTP

Download Chilkat IMAP ActiveX

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
'  Create a MailMan for the purpose
'  of unlocking the component.
set mailman = Server.CreateObject("Chilkat.MailMan2")
mailman.UnlockComponent "anything for 30-day trial"

set email = Server.CreateObject("Chilkat.Email2")

'  Adding attachments, HTML/plain-text bodies, etc can be done
'  in any order:

'  Add an attachment

contentType = email.AddFileAttachment("hamlet.zip")
If (contentType = vbNullString ) Then
    Response.Write Server.HtmlEncode(email.LastErrorText) & "<br>"

End If

'  Add some headers:
email.Subject = "This is a complex email"
email.AddTo "Chilkat Support","support@chilkatsoft.com"
email.From = "Matt <matt@chilkatsoft.com>"

'  Add a plain-text body:
email.AddPlainTextAlternativeBody "This is the plain-text body"

'  Add an image that will be embedded in the HTML body.
'  The contentType as derived from the file extension is returned.

contentId = email.AddRelatedFile("dude.gif")

'  Add an HTML body:

html = "<html><body><b>This is the HTML body</b><br><img src=""cid:" & contentId & """></body></html>"

email.AddHtmlAlternativeBody html

'  Save the email as a .eml

success = email.SaveEml("complex.eml")
If (success <> 1) Then
    Response.Write Server.HtmlEncode(email.LastErrorText) & "<br>"
Else
    Response.Write Server.HtmlEncode("Created email!") & "<br>"
End If

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com