|
|
Receive ASP Uploads in Memory
Demonstrates how to receive an ASP upload in memory, and then use the uploaded files directly without ever saving to disk. This example adds the uploaded files as attachments to an email and sends the email.
<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' The Chilkat ASP Upload component is freeware.
' The UploadRcv object receives uploads in ASP.
' It can be used to save uploaded files to the web server,
' or to save directly to memory for immediate access.
set receiver = Server.CreateObject("Chilkat_9_5_0.UploadRcv")
' Do not save uploads to the filesystem:
receiver.SaveToUploadDir = 0
' Don't allow anything over 1MB
receiver.SizeLimitKB = 1000
' Set a timeout just in case something hangs
' This is a 20-second timeout:
receiver.IdleTimeoutMs = 20000
' Consume the upload.
success = receiver.Consume()
If (success = 0) Then
'
Response.Write receiver.LastErrorHtml
Else
' Display the files received into memory
'
Response.Write "<p>Num file received: " & receiver.NumFilesReceived & "</p>"
If (receiver.NumFilesReceived > 0) Then
For i = 0 To receiver.NumFilesReceived - 1
'
Response.Write "<p>Received " & receiver.GetFilename(i) & " (" & receiver.GetFileSize(i) & " bytes)</p>"
Next
End If
'
Response.Write "<p>Success in receiving uploads.</p>"
End If
' The Chilkat Upload component is freeware.
' However, the Chilkat Email component is not freeware.
' This example will now add the uploaded files as attachments
' to an email and send.
' The mailman object is used for sending and receiving email.
set mailman = Server.CreateObject("Chilkat_9_5_0.MailMan")
' Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
Response.Write "Component unlock failed" & "<br>"
End If
' Set the SMTP server.
mailman.SmtpHost = "smtp.chilkatsoft.com"
' Set the SMTP login/password (if required)
mailman.SmtpUsername = "myUsername"
mailman.SmtpPassword = "myPassword"
' Create a new email object
set email = Server.CreateObject("Chilkat_9_5_0.Email")
email.Subject = "This is a test"
email.Body = "This is a test"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"
' Add the uploaded files as attachments.
' Note: The uploads are never saved to the web server's filesystem.
For i = 0 To receiver.NumFilesReceived - 1
email.AddDataAttachment receiver.GetFileData(i),receiver.GetFilename(i)
Next
' Call SendEmail to connect to the SMTP server and send.
' The connection (i.e. session) to the SMTP server remains
' open so that subsequent SendEmail calls may use the
' same connection.
success = mailman.SendEmail(email)
If (success <> 1) Then
Response.Write mailman.LastErrorText & "<br>"
End If
' Some SMTP servers do not actually send the email until
' the connection is closed. In these cases, it is necessary to
' call CloseSmtpConnection for the mail to be sent.
' Most SMTP servers send the email immediately, and it is
' not required to close the connection. We'll close it here
' for the example:
success = mailman.CloseSmtpConnection()
If (success <> 1) Then
Response.Write "Connection to SMTP server not closed cleanly." & "<br>"
End If
Response.Write "Mail Sent!" & "<br>"
%>
</body>
</html>
|
