Get Email Size Information

Download Chilkat IMAP ActiveX

ASP script showing how to Read IMAP Mail Headers and Retrieve the Complete Email Size

<html>
<head>
<title>IMAP Get Email Size Info</title>
</head>
<body>
<%
' ASP Script to Read IMAP Mail Headers and Retrieve the Complete Email Size
set imap = Server.CreateObject("Chilkat.Imap")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = imap.UnlockComponent("30-day trial")
if unlocked then

	' Connect to the IMAP server and login
	' Returns 0 if failed, but for the example we are not handling it.
	' Extended error information is available in the
	' imap.LastErrorHtml property
	success = imap.Connect("localhost")
	success = imap.Login("chilkat","chilkat")
	
	' Select a mailbox for reading.
    success = imap.SelectMailbox("Inbox")
    
    ' Get all the messages
    Set msgSet = imap.Search("ALL", 1)

    ' Fetch all the mail into a bundle object.
    Set bundle = imap.FetchHeaders(msgSet)
    
    ' Loop over the bundle and display the Subject and Size.
    Response.write "<table><tr><td><b>Subject</b></td><td><b>Size</b></td></tr>"
    For i = 0 To bundle.MessageCount - 1
        Set email = bundle.GetEmail(i)
        
        ' Do not use email.Size property here, because we retrieved the headers
        ' only. email.Size only applies if we retrieved the entire email.
        ' Instead, use imap.GetMailSize
        totalEmailSize = imap.GetMailSize(email)
        
        Response.write "<tr>"
        Response.write "<td width=500>" & email.Subject & "</td>"
        Response.write "<td>" & totalEmailSize & "</td>"
        Response.write "</tr>"
    Next
    Response.write "</table>"
		
	imap.Logout
	imap.Disconnect
	
end if

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com