Get Email Attachment Information

Download Chilkat IMAP ActiveX

ASP script showing how to read IMAP email headers and retrieve the attachment filenames and sizes.

<html>
<head>
<title>IMAP Get Email Attachment Info</title>
</head>
<body>
<%
' ASP Script to Read IMAP Attachment Information
set imap = Server.CreateObject("Chilkat.Imap")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = imap.UnlockComponent("30-day trial")
if unlocked then

	' Connect to the IMAP server and login
	' Returns 0 if failed, but for the example we are not handling it.
	' Extended error information is available in the
	' imap.LastErrorHtml property
	success = imap.Connect("localhost")
	success = imap.Login("chilkat","chilkat")
	
	' Select a mailbox for reading.
    success = imap.SelectMailbox("Inbox")
    
    ' Get all the messages
    Set msgSet = imap.Search("ALL", 1)

    ' Fetch all the mail into a bundle object.
    Set bundle = imap.FetchHeaders(msgSet)
    
    ' Loop over the bundle and display the From and Subject.
    Response.write "<table><tr><td><b>Filename</b></td><td><b>Size</b></td></tr>"
    For i = 0 To bundle.MessageCount - 1
        Set email = bundle.GetEmail(i)
        
        ' Do not use email.NumAttachments here, because we retrieved the headers
        ' only. NumAttachments only applies if we retrieved the entire email.
        ' Instead, use imap.GetMailNumAttach
        numAttachments = imap.GetMailNumAttach(email)
        for j = 0 to numAttachments - 1
        
        	' Get the attachment filename and size.
	        Response.write "<tr>"
	        Response.write "<td>" & imap.GetMailAttachFilename(email,j) & "</td>"
	        Response.write "<td>" & imap.GetMailAttachSize(email,j) & "</td>"
	        Response.write "</tr>"
	    Next
    Next
    Response.write "</table>"
		
	imap.Logout
	imap.Disconnect
	
end if

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com