Display IMAP Email in all Languages

Download Chilkat IMAP ActiveX

This ASP script shows how to read email headers (summary information) from an IMAP server, and display the header information using the utf-8 charset, which is capable of handling all languages.

<html>
<head>
<meta HTTP-EQUIV="Content-Type" CONTENT="text/html; charset=utf-8">
<title>Display IMAP Email in all Languages</title>
</head>
<body>
<%
' ASP Script to Read and Display IMAP Mail in all Languages
set imap = Server.CreateObject("Chilkat.Imap")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = imap.UnlockComponent("30-day trial")
if unlocked then

	' Connect to the IMAP server and login
	' Returns 0 if failed, but for the example we are not handling it.
	' Extended error information is available in the
	' imap.LastErrorHtml property
	success = imap.Connect("localhost")
	success = imap.Login("chilkat","chilkat")
	
	' Select a mailbox for reading.
    success = imap.SelectMailbox("Inbox")
    
    ' Get all the messages
    Set msgSet = imap.Search("ALL", 1)

    ' Fetch all the mail into a bundle object.
    Set bundle = imap.FetchHeaders(msgSet)
    
    ' Loop over the bundle and display the From and Subject.
    Response.write "<table>"
    For i = 0 To bundle.MessageCount - 1
        Set email = bundle.GetEmail(i)
        
        Response.write "<tr>"
        ' Get the email From name/address in utf-8
        Response.write "<td width=200 valign=top>"
        if Len(email.From) > 0 then
        	Response.BinaryWrite  email.GetMbHeaderField("From","utf-8")
        else
        	Response.write "&nbsp;"
        end if
        Response.write "</td>"
        Response.write "<td valign=top>" & email.LocalDate & "</td>"
        ' Get the email subject in utf-8
        Response.write "<td width=400 valign=top>"
        if Len(email.Subject) > 0 then
        	Response.BinaryWrite email.GetMbHeaderField("Subject","utf-8")
        else
        	Response.write "&nbsp;"
        end if
        Response.write "</td>"
        Response.write "<td valign=top>" & email.NumAttachments & "</td>"
        
        Response.write "</tr>"
    Next
    Response.write "</table>"
	
	imap.Logout
	imap.Disconnect
	
end if

%>
</body>
</html>

' All languages are supported, including Japanese, Korean, Chinese, Arabic, Hebrew, Thai, Russian, Greek,
Turkish, Romanian, Ukrainian, Croation, Czech, and all other European and Central-European languages.

Need a specific example? Send a request to support@chilkatsoft.com