AES Encrypt with Initialization Vector

Download Chilkat Crypt ActiveX

This ASP script show how to do AES encryption using an initialization vector of 16 bytes. (The IV must always be 16 bytes). It also shows how to set the binary secret key directly from a byte array.

<html>
<head>
<title>AES Encrypt Strings in ASP using an initialization vector and binary secret key</title>
</head>
<body>
<%
' Create an encryption object
set crypt = Server.CreateObject("Chilkat.Crypt2")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = crypt.UnlockComponent("30-day trial")
if unlocked then

	' Note: AES encryption pads to a multiple of 16 bytes.
	crypt.CryptAlgorithm = "aes"
	' Cipher Block Chaining is the default and most common mode for AES.
	' You can also select "ecb" for Electronic Cookbook.
	crypt.CipherMode = "cbc"
	' The key length can be 128, 192, or 256
	crypt.KeyLength = 128
	
                ' Create a secret key and IV
	Dim pk(15)
	Dim iv(15)
	For i = 0 to 15 
	        pk(i) = CByte(i*15) 
	        iv(i) = CByte((15-i) * 13) 
	Next 

	crypt.SecretKey = pk 
	crypt.IV = iv 
	
	' Encrypt a string. Return the encrypted data as a URL-encoded string.
	crypt.EncodingMode = "url"
	Response.Write "<br><br><b>URL-encoded Encrypted String:</b><br>"
	Response.Write crypt.EncryptStringENC("123")
		
	' Encrypt a string. Return the encrypted data as a base64-encoded string.
	crypt.EncodingMode = "base64"
	Response.Write "<br><br><b>Base64 Encrypted String:</b><br>"
	Response.Write crypt.EncryptStringENC("123")
		
	' Encrypt a string. Return the encrypted data as a hex-encoded string.
	crypt.EncodingMode = "hex"
	Response.Write "<br><br><b>Hexidecimalized Encrypted String:</b><br>"
	Response.Write crypt.EncryptStringENC("123")
			
else
	Response.Write "Crypt object is not unlocked!"
end if
 
%>
</body>
</html>