Select Encryption Algorithm with SMTP Encrypted Email

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

Demonstrates how to select the encryption algorithm and strength (key size) when sending encrypted email.

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
'  The mailman object is used for sending and receiving email.
set mailman = Server.CreateObject("Chilkat_9_5_0.MailMan")

'  Any string argument automatically begins the 30-day trial.
success = mailman.UnlockComponent("30-day trial")
If (success <> 1) Then
    Response.Write "Component unlock failed" & "<br>"

End If

'  Set the SMTP server.
mailman.SmtpHost = "smtp.comcast.net"

'  Create a new email object
set email = Server.CreateObject("Chilkat_9_5_0.Email")

email.Subject = "This email is encrypted"
email.Body = "This is a digitally encrypted mail"
email.From = "Chilkat Support <support@chilkatsoft.com>"
email.AddTo "Chilkat Admin","admin@chilkatsoft.com"

'  In this example, we've already installed the certificate for "admin@chilkatsoft.com"
'  in the current user's personal certificate store.
'  If the email.SendEncrypted property is set, Chilkat will
'  automatically search for and use the first non-expired certificate
'  matching the recipient's email address.  Chilkat searches
'  the Current User's Personal certificate store, as well
'  as the Local Machine's Personal certificate store.
'  Run certmgr.msc to view the certs in the Current User's
'  certificate store.
email.SendEncrypted = 1

'  Use the CSP object to select an encryption algorithm:
set csp = Server.CreateObject("Chilkat_9_5_0.Csp")
'  Make sure we're using the enhanced provider, which provides
'  access to stronger algorithms.
csp.SetProviderMicrosoftEnhanced 

'  Select 168-bit 3DES (i.e. 192-bit DES if you include the parity bits)
csp.SetEncryptAlgorithm "3DES"

'  Tell the email to use this CSP:
email.SetCSP csp

success = mailman.SendEmail(email)
If (success <> 1) Then
    Response.Write mailman.LastErrorText & "<br>"
Else
    '  Examine the LastErrorText anyway, so we can see
    '  that 3DES was used...
    '  You should see these lines in the log:
    '  alg_name: 3DES
    '  alg_bits: 168
    Response.Write mailman.LastErrorText & "<br>"
End If


%>
</body>
</html>