(Classic ASP) S3 Delete Bucket Object

Deletes an object in a bucket.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example requires the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Rest")
set rest = Server.CreateObject("Chilkat.Rest")

' Connect to the Amazon AWS REST server.
bTls = 1
port = 443
bAutoReconnect = 1
success = rest.Connect("s3.amazonaws.com",port,bTls,bAutoReconnect)

' ----------------------------------------------------------------------------
' Important: For buckets created in regions outside us-east-1,
' there are three important changes that need to be made.
' See Working with S3 Buckets in Non-us-east-1 Regions for the details.
' ----------------------------------------------------------------------------

' Provide AWS credentials for the REST call.
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.AuthAws")
set authAws = Server.CreateObject("Chilkat.AuthAws")
authAws.AccessKey = "AWS_ACCESS_KEY"
authAws.SecretKey = "AWS_SECRET_KEY"
authAws.ServiceName = "s3"
success = rest.SetAuthAws(authAws)

'  Set the bucket name via the HOST header.
'  In this case, the bucket name is "chilkat100".
rest.Host = "chilkat100.s3.amazonaws.com"

' This example deletes the object named "Abc.ics"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbResponse = Server.CreateObject("Chilkat.StringBuilder")
success = rest.FullRequestNoBodySb("DELETE","/Abc.ics",sbResponse)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( rest.LastErrorText) & "</pre>"
    Response.End
End If

' If successfully deleted, the response status code is 204 and the response body text will be empty.
statusCode = rest.ResponseStatusCode
Response.Write "<pre>" & Server.HTMLEncode( "Response status code = " & statusCode) & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( "Response text = ") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( sbResponse.GetAsString()) & "</pre>"

%>
</body>
</html>