RSA Encrypting Symmetric Secret Key

Download Chilkat RSA ActiveX

Download Chilkat Crypt ActiveX

The RSA encryption algorithm is computationally expensive. It is not the best choice for encrypting large amounts of data. Symmetric encryption algorithms such as AES (i.e. Rijndael) or Blowfish are much more efficient. A typical application scenario is that you want to send encrypted messages to a partner, but you don't want to send the symmetric key unprotected. A solution is to generate a public/private RSA key pair and provide your partner with the public key (in advance). You may then encrypt the symmetric algorithm's key using the RSA private key. Next, encrypt the message using the symmetric algorithm, and send your partner both the encrypted key and encrypted message. Your partner decrypts by first RSA decrypting the key, and then using it to decrypt the message. One typical use of the RSA algorithm is to encrypt a symmetric encryption algorithm key so that it can be sent to

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set rsa = Server.CreateObject("Chilkat.Rsa")

success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Response.Write "RSA component unlock failed" & "<br>"

End If

set crypt = Server.CreateObject("Chilkat.Crypt2")
success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Response.Write "Crypt component unlock failed" & "<br>"

End If

'  Load a public/private key pair from a .snk key file.
'  Assume you have already provided your partner with
'  the public key part of the key pair.
xmlKey = rsa.SnkToXml("chilkat2.snk")

'  Alternatively, you may generate a public/private key pair
'  by calling GenerateKey (as shown in the commented-out line
'  below).  If you do this, comment out the lines that call
'  ImportPrivateKey and ImportPublicKey.
' success = rsa.GenerateKey(2048);

'  Import the private key into the RSA instance.
rsa.ImportPrivateKey xmlKey

'  Our message data will be encrypted using 128-bit AES
'  encryption, using CBC (cipher-block chaining).
crypt.CryptAlgorithm = "aes"
crypt.CipherMode = "cbc"
crypt.KeyLength = 128

'  Generate a 128-bit secret key from a passphrase and return it as a hex string.
secretKey = crypt.GenEncodedSecretKey("secret","hex")
Response.Write "Unencrypted Key: " & secretKey & "<br>"

'  Use the key we generated:
crypt.SetEncodedKey secretKey,"hex"

'  RSA encrypt the secret key and return as a hex string:
rsa.EncodingMode = "hex"
bUsePrivateKey = 0
encryptedKey = rsa.EncryptStringENC(secretKey,bUsePrivateKey)

'  Symmetric encrypt a message.  For this example the message
'  is very short, but typically this is where a large amount
'  of data may be encrypted.
crypt.EncodingMode = "base64"
encryptedText = crypt.EncryptStringENC("Hello World!")

'  Show our encrypted key and encrypted text:
Response.Write "Encrypted Key: " & encryptedKey & "<br>"
Response.Write "Encrypted Text: " & encryptedText & "<br>"

'  Assume we sent these strings to our partner...

'  Here's what we do at the partner end:
rsa.ImportPublicKey xmlKey

'  First, decrypt the encryptedKey:
bUsePrivateKey = 1
decryptedKey = rsa.DecryptStringENC(encryptedKey,bUsePrivateKey)
Response.Write "Decrypted Key: " & decryptedKey & "<br>"

'  Set our crypt object's properties and secret key:
set crypt2 = Server.CreateObject("Chilkat.Crypt2")
crypt2.CryptAlgorithm = "aes"
crypt2.CipherMode = "cbc"
crypt2.KeyLength = 128
crypt2.EncodingMode = "base64"
crypt2.SetEncodedKey decryptedKey,"hex"

'  Decrypt the message:
decryptedText = crypt2.DecryptStringENC(encryptedText)
Response.Write "Decrypted Text: " & decryptedText & "<br>"
%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com