RSA Encrypt and Decrypt Credit Card Numbers

ASP sample code to RSA public-key encrypt and decrypt credit card numbers. The RSA key is loaded from an unencrypted PKCS8 file. Chilkat provides many ways of setting the key -- loading from both encrypted and unencrypted PEM, PKCS8, DER, PVK, etc. Keys may be loaded from files or in-memory representations. (The RSA component also provides the ability to generate RSA keys.)

Download 32-bit Chilkat RSA ActiveX (.msi)

Download All 32-bit Chilkat ActiveX Components (.zip)

Download All 64-bit Chilkat ActiveX Components (.zip)

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set rsa = Server.CreateObject("Chilkat.Rsa")

success = rsa.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode(rsa.LastErrorText) & "</pre>"

End If

set key = Server.CreateObject("Chilkat.PrivateKey")

'  Load an RSA private key from a PKCS8 file:
success = key.LoadPkcs8File("rsaPrivateKey.p8")
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode(key.LastErrorText) & "</pre>"

End If

'  Get the key as XML:

keyXml = key.GetXml()

'  We'll encrypt with the public key and decrypt with the private
'  key.  (It's also possible to do the reverse.)
'  Note: An RSA private key is composed of different parts internally: modulus, exponent, P, Q, etc.
'  An RSA public-key is a sub-set of the private key.
'  Therefore, when you have a private key, you really have
'  both public and private keys.
success = rsa.ImportPublicKey(keyXml)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode(rsa.LastErrorText) & "</pre>"

End If

'  Encrypt a VISA credit card number:
'  1234-5678-0000-9999
ccNumber = "1234567800009999"

usePrivateKey = 0
rsa.EncodingMode = "base64"
encryptedStr = rsa.EncryptStringENC(ccNumber,usePrivateKey)
Response.Write "<pre>" & Server.HTMLEncode( "Encrypted:") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( encryptedStr) & "</pre>"

'  Now decrypt:
set rsaDecryptor = Server.CreateObject("Chilkat.Rsa")

rsaDecryptor.EncodingMode = "base64"
rsaDecryptor.ImportPrivateKey keyXml

usePrivateKey = 1
decryptedStr = rsaDecryptor.DecryptStringENC(encryptedStr,usePrivateKey)

Response.Write "<pre>" & Server.HTMLEncode( "Decrypted:") & "</pre>"
Response.Write "<pre>" & Server.HTMLEncode( decryptedStr) & "</pre>"

'  Important: RSA encryption should only be used to encrypt small amounts of data.
'  It is typically used for encrypting symmetric encryption
'  keys such that a symmetric encryption algorithm, such as
'  AES is then used to encrypt/decrypt bulk data.

%>
</body>
</html>