ASP Script to Read and Display POP3 Email

Download Chilkat Email ActiveX for ASP and Applications

More ASP POP3 Examples

More ASP SMTP Examples

More ASP Email Examples

ASP script showing how to read and display POP3 email.

See Also: ASP script to send email.

ASP to Display Email "From" Name/Address and Subject

This script reads email headers and creates a button to display each
email in a separate window. (The target script is listed below.)

<%@ LANGUAGE="VBSCRIPT" %>
<HTML>
<HEAD>
<TITLE>How to Read Email in ASP</TITLE>
</HEAD>
<BODY>

<%
	' Create a mailman
	set mailman = Server.CreateObject("Chilkat.MailMan2")

	' Any code begins the 30-day trial
	mailman.UnlockComponent "30-day trial"

	mailman.MailHost = "mail.chilkatsoft.com"
	mailman.PopUsername = "login"
	mailman.PopPassword = "password"
	
	' Copy the email from the POP3 server without removing it.
	set bundle = mailman.GetAllHeaders(0)
	if (not (bundle is nothing)) then
		Response.write "<table border=1 cellpadding=5>"
		response.write "<tr>"
		response.write "<td><b>From</b></td>"
		response.write "<td><b>Subject</b></td>"
		response.write "<td><b>Display</b></td>"
		response.write "</tr>"
		
		' Loop over each email in the bundle.
		n = bundle.MessageCount
		for i = 0 to n-1
			set email = bundle.GetEmail(i)
			response.write "<tr>"
			response.write "<td>"+Server.HTMLEncode(email.From)+"</td>"
			response.write "<td>"+Server.HTMLEncode(email.Subject)+"</td>"
			response.write "<td><form method=""post"" action=""DisplayEmail.asp"" target=""emailDetail"">"
  			response.write "<input type=""submit"" name=""Submit"" value=""Display"">"
			response.write "<input type=""hidden"" name=""Uidl"" value=""" + email.Uidl +"""></form></td>"
			
			response.write "</tr>"
		next
		response.write "</table><br>"
	end if
%>
    <br><b>HTML Log:</b><br>
<%
    Response.write mailman.LastErrorHtml

	' Standard ASP cleanup of objects
	Set email = Nothing
	Set mailman = Nothing

%>

</BODY>
</HTML>

ASP to Display Email Plain-Text or HTML Body

This will display an email in any language in an ASP page.

<%@ Language=VBScript %>

<%
	' Create a mailman
	set mailman = Server.CreateObject("Chilkat.MailMan2")

	' Any code starts the 30-day trial
	mailman.UnlockComponent "30-day trial"

	mailman.MailHost = "mail.chilkatsoft.com"
	mailman.PopUsername = "login"
	mailman.PopPassword = "password"

	set email = mailman.FetchEmail(Request.Form("Uidl"))
	
	if (not (email is nothing)) then
		
		' Preferably display the HTML version
		if (email.HasHtmlBody() = 1) then
			' Regardless of the charset of the email, convert it all to utf-8.
			' This allows email of any language to be displayed in the ASP page.
			email.Charset = "utf-8"
			Response.BinaryWrite email.GetMbHtmlBody("utf-8")
		elseif (email.HasPlainTextBody() = 1) then
			%>
			<html>
			<head>
			<meta HTTP-EQUIV="Content-Type" CONTENT="text/html;CHARSET=utf-8">
			<title>ASP to Display Plain-Text Email</title>
			</head>
			<body bgcolor="#FFFFFF">
<pre>
<%
' Get the plain-text body as utf-8 character data.
' This allows any email in any language to be displayed correctly.
Response.BinaryWrite email.GetMbPlainTextBody("utf-8")
%>
</pre>
			</body>
			</html>
		<%
		else
			Response.write "This email has no body."
		end if
		
	end if
%>

Relevant keywords: ASP Tutorial, ASP Script, ASP Application, ASP Software, ASP Code, ASP Programming, ASP Component, Free ASP Script, ASP Email, ASP Help, ASP Example, ASP Source Code, ASP Developer, ASP Mail, ASP XML, ASP Sample

Need a specific example? Send a request to support@chilkatsoft.com