(Classic ASP) Download Web Page to MHT and Extract Images (all in memory)

Downloads a web page to an MHT archive (in memory) and then extracts each image to a byte array in memory.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' This example assumes the Chilkat API to have been previously unlocked.
' See Global Unlock Sample for sample code.

' Note: This URL exists at the time of writing and testing this example (on 12-June-2020)
' However, it will surely not continue to exist for very long.
' You should choose a different URL.  (Any web page with images will do.)
url = "https://www.fendi.com/it/abbigliamento-uomo/cravatta-fxc160a3nwf0qg2"

' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Mht")
set mht = Server.CreateObject("Chilkat.Mht")

' Downloads to an MHT string.
' MHT is just MIME, which is the same format as an email but with different semantics.
mhtStr = mht.GetMHT(url)
If (mht.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( mht.LastErrorText) & "</pre>"
    Response.End
End If

' We can still treat the MHT MIME as an email and iterate over the "related items".
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.Email")
set email = Server.CreateObject("Chilkat.Email")
success = email.SetFromMimeText(mhtStr)
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( email.LastErrorText) & "</pre>"
    Response.End
End If

numRelatedItems = email.NumRelatedItems
i = 0
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.StringBuilder")
set sbContentType = Server.CreateObject("Chilkat.StringBuilder")
Do While i < numRelatedItems
    success = sbContentType.SetString(email.GetRelatedContentType(i))
    Response.Write "<pre>" & Server.HTMLEncode( "Content-Type: " & sbContentType.GetAsString()) & "</pre>"

    If (sbContentType.StartsWith("image/",0) = 1) Then
        ' We have an image.
        ' Get the image data.
        imageData = email.GetRelatedData(i)

        ' Do what you need with the image data..
    End If

    i = i + 1
Loop

%>
</body>
</html>