(Classic ASP) Create JWK Set Containing Certificates

Demonstrates how to create a JWK Set containing N certificates.

Note: This example requires Chilkat v11.0.0 or greater.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
success = 0

' This example creates the following JWK Set from two certificates:

' {
'   "keys": [
'     {
'       "kty": "RSA",
'       "use": "sig",
'       "kid": "BB8CeFVqyaGrGNuehJIiL4dfjzw",
'       "x5t": "BB8CeFVqyaGrGNuehJIiL4dfjzw",
'       "n": "nYf1jpn7cFdQ...9Iw",
'       "e": "AQAB",
'       "x5c": [
'         "MIIDBTCCAe2...Z+NTZo"
'       ]
'     },
'     {
'       "kty": "RSA",
'       "use": "sig",
'       "kid": "M6pX7RHoraLsprfJeRCjSxuURhc",
'       "x5t": "M6pX7RHoraLsprfJeRCjSxuURhc",
'       "n": "xHScZMPo8F...EO4QQ",
'       "e": "AQAB",
'       "x5c": [
'         "MIIC8TCCAdmgA...Vt5432GA=="
'       ]
'     }
'   ]
' }

' First get two certificates from files.
set cert1 = Server.CreateObject("Chilkat.Cert")
success = cert1.LoadFromFile("qa_data/certs/brasil_cert.pem")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( cert1.LastErrorText) & "</pre>"
    Response.End
End If

set cert2 = Server.CreateObject("Chilkat.Cert")
success = cert2.LoadFromFile("qa_data/certs/testCert.cer")
If (success = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( cert2.LastErrorText) & "</pre>"
    Response.End
End If

' We'll need this crypt object re-encode the SHA1 thumbprint from hex to base64.
set crypt = Server.CreateObject("Chilkat.Crypt2")

set json = Server.CreateObject("Chilkat.JsonObject")

' Let's begin with the 1st cert:
json.I = 0
success = json.UpdateString("keys[i].kty","RSA")
success = json.UpdateString("keys[i].use","sig")

hexThumbprint = cert1.Sha1Thumbprint
base64Thumbprint = crypt.ReEncode(hexThumbprint,"hex","base64")
success = json.UpdateString("keys[i].kid",base64Thumbprint)
success = json.UpdateString("keys[i].x5t",base64Thumbprint)

' (We're assuming these are RSA certificates)
' To get the modulus (n) and exponent (e), we need to get the cert's public key and then get its JWK.
set pubKey = Server.CreateObject("Chilkat.PublicKey")
success = cert1.GetPublicKey(pubKey)

set pubKeyJwk = Server.CreateObject("Chilkat.JsonObject")
success = pubKeyJwk.Load(pubKey.GetJwk())
success = json.UpdateString("keys[i].n",pubKeyJwk.StringOf("n"))
success = json.UpdateString("keys[i].e",pubKeyJwk.StringOf("e"))

' Now add the entire X.509 certificate 
success = json.UpdateString("keys[i].x5c[0]",cert1.GetEncoded())

' Now do the same for cert2..
json.I = 1

success = json.UpdateString("keys[i].kty","RSA")
success = json.UpdateString("keys[i].use","sig")

hexThumbprint = cert2.Sha1Thumbprint
base64Thumbprint = crypt.ReEncode(hexThumbprint,"hex","base64")
success = json.UpdateString("keys[i].kid",base64Thumbprint)
success = json.UpdateString("keys[i].x5t",base64Thumbprint)
success = cert2.GetPublicKey(pubKey)

success = pubKeyJwk.Load(pubKey.GetJwk())
success = json.UpdateString("keys[i].n",pubKeyJwk.StringOf("n"))
success = json.UpdateString("keys[i].e",pubKeyJwk.StringOf("e"))

' Now add the entire X.509 certificate 
success = json.UpdateString("keys[i].x5c[0]",cert2.GetEncoded())

' Emit the JSON..
json.EmitCompact = 0
Response.Write "<pre>" & Server.HTMLEncode( json.Emit()) & "</pre>"

%>
</body>
</html>