(Classic ASP) JSON: Nested Array

Here we have a JSON object that contains nested arrays. This example demonstrates how to access the contents of the nested arrays.

{
 "numbers" : [ 
    ["even", 2, 4, 6, 8], 
    ["prime", 2, 3, 5, 7, 11, 13] 
  ] }

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
' For versions of Chilkat < 10.0.0, use CreateObject("Chilkat_9_5_0.JsonObject")
set json = Server.CreateObject("Chilkat.JsonObject")

' This is the above JSON with whitespace chars removed (SPACE, TAB, CR, and LF chars).
' The presence of whitespace chars for pretty-printing makes no difference to the Load
' method. 
jsonStr = "{ ""numbers"" : [ [""even"", 2, 4, 6, 8], [""prime"", 2, 3, 5, 7, 11, 13] ] }"

success = json.Load(jsonStr)
If (success <> 1) Then
    Response.Write "<pre>" & Server.HTMLEncode( json.LastErrorText) & "</pre>"
    Response.End
End If

' Get the value of the "numbers" object, which is an array that contains JSON arrays.
' outerArray is a Chilkat.JsonArray
Set outerArray = json.ArrayOf("numbers")
If (json.LastMethodSuccess = 0) Then
    Response.Write "<pre>" & Server.HTMLEncode( "numbers array not found.") & "</pre>"
    Response.End
End If

numArrays = outerArray.Size

For i = 0 To numArrays - 1

    ' innerArray is a Chilkat.JsonArray
    Set innerArray = outerArray.ArrayAt(i)

    ' The first item in the innerArray is a string
    Response.Write "<pre>" & Server.HTMLEncode( innerArray.StringAt(0) & ":") & "</pre>"

    numInnerItems = innerArray.Size

    For j = 1 To numInnerItems - 1

        Response.Write "<pre>" & Server.HTMLEncode( "  " & innerArray.IntAt(j)) & "</pre>"

    Next

Next


%>
</body>
</html>