HTTPS Upload Files to Web Server using SSL

Download Chilkat HTTP ActiveX

This example shows how to upload one or more files over SSL (HTTPS) to a web server.

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%

set http = Server.CreateObject("Chilkat.Http")

'  Any string unlocks the component for the 1st 30-days.
success = http.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Response.Write Server.HtmlEncode(http.LastErrorText) & "<br>"

End If

'  Build a HTTPS upload request with the files to be uploaded:
set req = Server.CreateObject("Chilkat.HttpRequest")
req.UseUpload 

'  The URL we'll be posting to is:
'  http://www.yourwebserver123abc.com/ConsumeUpload.aspx
'  Therefore, the path part of the URL is:
req.Path = "/ConsumeUpload.aspx"

'  Note: You'll need to edit this example to upload to your
'  own web server.

'  Add some files to the request:
'  The 1st argument is an arbitrary name.  It's the POST form field name.
'  The 2nd argument is the filename currently existing on
'  the local filesystem.  It may include an absolute or relative
'  path, or no path at all if it's in the current working directory.
success = req.AddFileForUpload("file1","hamlet.xml")
If (success <> 1) Then
    Response.Write Server.HtmlEncode(req.LastErrorText) & "<br>"

End If

success = req.AddFileForUpload("file2","dude.gif")
If (success <> 1) Then
    Response.Write Server.HtmlEncode(req.LastErrorText) & "<br>"

End If

'  Send the HTTPS POST and get the response.  Note: This is a blocking call.
'  The method does not return until the full HTTPS response is received.

domain = "www.yourwebserver123abc.com"
'  The only difference in coding between non-SSL and SSL is
'  the setting of these two arguments to SynchronousRequest:
port = 443
ssl = 1

Set resp = http.SynchronousRequest(domain,port,ssl,req)
If (resp Is Nothing ) Then
    Response.Write Server.HtmlEncode(http.LastErrorText) & "<br>"
Else
    '  Display the HTML source of the page returned.
    Response.Write Server.HtmlEncode(resp.BodyStr) & "<br>"
End If

%>
</body>
</html>