56-bit DES Encryption, ECB, CBC modes

56-bit DES encryption. The Chilkat encryption component supports DES in both ECB (Electronic Cookbook) and CBC (Cipher-Block Chaining) cipher modes.

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set crypt = Server.CreateObject("Chilkat_9_5_0.Crypt2")

success = crypt.UnlockComponent("Anything for 30-day trial")
If (success <> 1) Then
    Response.Write "Crypt component unlock failed" & "<br>"

End If

'  Specify DES for the encryption algorithm:
crypt.CryptAlgorithm = "des"

'  CipherMode may be "ecb" or "cbc"
crypt.CipherMode = "cbc"

'  KeyLength must be 64.  DES is technically 56-bits;
'  the most-significant bit of each key byte is a parity bit,
'  so we must indicate a KeyLength of 64, which includes
'  the parity bits.
crypt.KeyLength = 64

'  The padding scheme determines the contents of the bytes
'  that are added to pad the result to a multiple of the
'  encryption algorithm's block size.  DES has a block
'  size of 8 bytes, so encrypted output is always
'  a multiple of 8.
crypt.PaddingScheme = 0

'  EncodingMode specifies the encoding of the output for
'  encryption, and the input for decryption.
'  It may be "hex", "url", "base64", or "quoted-printable".
crypt.EncodingMode = "hex"

'  An initialization vector is required if using CBC or CFB modes.
'  ECB mode does not use an IV.
'  The length of the IV is equal to the algorithm's block size.
'  It is NOT equal to the length of the key.
ivHex = "0001020304050607"
crypt.SetEncodedIV ivHex,"hex"

'  The secret key must equal the size of the key.  For
'  DES, the key must be 8 bytes (i.e. 64-bits).
keyHex = "0001020304050607"
crypt.SetEncodedKey keyHex,"hex"

'  Encrypt a string...
'  The input string is 44 ANSI characters (i.e. 44 bytes), so
'  the output should be 48 bytes (a multiple of 8).
'  Because the output is a hex string, it should
'  be 96 characters long (2 chars per byte).
encStr = crypt.EncryptStringENC("The quick brown fox jumps over the lazy dog.")
Response.Write encStr & "<br>"

'  Now decrypt:
decStr = crypt.DecryptStringENC(encStr)
Response.Write decStr & "<br>"
%>
</body>
</html>