Export Public Key to RSA DER, OpenSSL DER/PEM, XML

Demonstrates how to export a digital certificate's public key to RSA DER, OpenSSL PEM or DER, or to XML format.

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
set cert = Server.CreateObject("Chilkat.Cert")

'  Th LoadByCommonName method searches the Windows
'  Current User Certificate Store and Local Machine Certificate
'  Store for a certificate whose common name (CN) matches
'  the argument:

success = cert.LoadByCommonName("Chilkat Software, Inc.")
If (success = 0) Then
    Response.Write Server.HtmlEncode("Failed to find certificate!") & "<br>"
Else

    '  Get the PublicKey object:

    Set pkey = cert.ExportPublicKey()
    If (Not (pkey Is Nothing )) Then

        '  Export the public key to an RSA DER file:
        pkey.SaveRsaDerFile "pubkey_rsa.der"

        '  Export to an OpenSSL DER file:
        pkey.SaveOpenSslDerFile "pubkey_openssl.der"

        '  Export to an OpenSSL PEM file:
        pkey.SaveOpenSslPemFile "pubkey_openssl.pem"

        '  Export to an XML file:
        pkey.SaveXmlFile "pubkey.xml"

        '  Get OpenSSL PEM string:
        Response.Write Server.HtmlEncode("OpenSSL PEM Public Key:") & "<br>"
        Response.Write Server.HtmlEncode(pkey.GetOpenSslPem()) & "<br>"

    Else
        Response.Write Server.HtmlEncode("No public key found!") & "<br>"
    End If

End If

'  The Chilkat Certificate, Certificate Store, Private Key,
'  Public Key, and Key Container classes / objects are freeware.

'  They are used by and included with the Chilkat Email,
'  Crypt, S/MIME, and other commercial Chilkat components.

%>
</body>
</html>