ASP Upload -- Receive uploaded files in ASP.

The Chilkat ASP Upload ActiveX component is freeware.

A live example may be tested at this URL: ASP Upload Live Test

Download Chilkat Upload ActiveX (freeware)

<html>
<head>
<meta http-equiv="Content-Type" content="text/html; charset=utf-8">
</head>
<body>
<%
'  The Chilkat ASP Upload component is freeware.
'  The UploadRcv object receives uploads in ASP.
'  It can be used to save uploaded files to the web server,
'  or to save directly to memory for immediate access.
set receiver = Server.CreateObject("Chilkat.UploadRcv")

'  Stream uploads to a directory:
receiver.SaveToUploadDir = 1
'  
receiver.UploadDir = Server.MapPath("data")

'  Don't allow anything over 1MB
receiver.SizeLimitKB = 1000

'  Set a timeout just in case something hangs
'  This is a 20-second timeout:
receiver.IdleTimeoutMs = 20000

'  Consume the upload.  Files are streamed to the UploadDir
success = receiver.Consume()
If (success = 0) Then
    Response.Write receiver.LastErrorHtml
Else
    '  Display the files received:
    Response.Write "<p>Num file received: " & receiver.NumFilesReceived & "</p>"
    If (receiver.NumFilesReceived > 0) Then
        For i = 0 To receiver.NumFilesReceived - 1
            Response.Write "<p>Received " &  receiver.GetFilename(i) &  " (" & receiver.GetFileSize(i) & " bytes)</p>"
        Next
    End If

Response.Write "<p>Success.</p>"
End If

Response.Flush()

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com