Delete Email from a Mailbox

Download Chilkat IMAP ActiveX

This ASP script shows how to delete email from an IMAP mailbox.

<html>
<head>
<title>Delete Email from an IMAP Mailbox</title>
</head>
<body>
<%
' ASP Script to Delete Email from an IMAP Mailbox
set imap = Server.CreateObject("Chilkat.Imap")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = imap.UnlockComponent("30-day trial")
if unlocked then

	' Connect to the IMAP server and login
	' Returns 0 if failed, but for the example we are not handling it.
	' Extended error information is available in the
	' imap.LastErrorHtml property
	success = imap.Connect("localhost")
	success = imap.Login("chilkat","chilkat")
	
	' Select a mailbox for reading.
    success = imap.SelectMailbox("Inbox")
    
    ' Get all the messages
    Set msgSet = imap.Search("ALL", 1)

    ' Fetch all the mail into a bundle object.
    Set bundle = imap.FetchHeaders(msgSet)
    
    ' Loop over the bundle and mark emails for deletion
    For i = 0 To bundle.MessageCount - 1
        Set email = bundle.GetEmail(i)
        
        ' If the email subject contains the substring "#SPAM#" then delete it.
        if InStr(email.Subject,"#SPAM#") then
        
        	Response.write "Marking:" & email.Subject & "<br>"
        	imap.SetMailFlag email,"Deleted",1
        	
        end if
    Next
	
	' Permanently removes from the currently selected mailbox 
	' all messages that have the \Deleted flag set.
	imap.Expunge
	
	imap.Logout
	imap.Disconnect
	
end if

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com