Get Full Email after Reading Header

Download Chilkat IMAP ActiveX

ASP script showing how to download a full email after reading only the header.

<html>
<head>
<title>Fetch Full Email from IMAP Server after Retrieving the Header</title>
</head>
<body>
<%
' ASP Script to Fetch the Entire Email after Retrieving only the Header
set imap = Server.CreateObject("Chilkat.Imap")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = imap.UnlockComponent("30-day trial")
if unlocked then

	' Connect to the IMAP server and login
	' Returns 0 if failed, but for the example we are not handling it.
	' Extended error information is available in the
	' imap.LastErrorHtml property
	success = imap.Connect("localhost")
	success = imap.Login("chilkat","chilkat")
	
	' Select a mailbox for reading.
    success = imap.SelectMailbox("Inbox")
    
    ' Get all the messages
    Set msgSet = imap.Search("ALL", 1)

    ' Fetch all the mail into a bundle object.
    Set bundle = imap.FetchHeaders(msgSet)
    
    ' Download the entire first email
    if bundle.MessageCount > 0 then
    	Set email = bundle.GetEmail(0)
    	
    	' The IMAP UID is saved by Chilkat in the ckx-imap-uid header field.
    	uid = Int(email.GetHeaderField("ckx-imap-uid"))
    	set fullEmail = imap.FetchSingle(uid,1)
    	
    	' Display the entire MIME email message.
    	Response.write "<pre>" & fullEmail.GetMime() & "</pre>"
    end if
    
		
	imap.Logout
	imap.Disconnect
	
end if

%>
</body>
</html>

Need a specific example? Send a request to support@chilkatsoft.com