Copy Mail from One Mailbox to Another

Chilkat ActiveX Downloads

ActiveX for 32-bit and 64-bit Windows

ASP script showing how to copy email from one mailbox to another. This is not a "move" operation, but a "copy" operation: the source email remains in the source mailbox.

<html>
<head>
<title>Copy Email from one Mailbox to Another</title>
</head>
<body>
<%
' ASP Script to Copy Email from one IMAP Mailbox to Another
set imap = Server.CreateObject("Chilkat_9_5_0.Imap")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = imap.UnlockComponent("30-day trial")
if unlocked then

	' Connect to the IMAP server and login
	' Returns 0 if failed, but for the example we are not handling it.
	' Extended error information is available in the
	' imap.LastErrorHtml property
	success = imap.Connect("localhost")
	success = imap.Login("chilkat","chilkat")
	
	' Select a mailbox for reading.
    success = imap.SelectMailbox("Inbox")
    
    ' Get all the messages
    Set msgSet = imap.Search("ALL", 1)
    
    ' Copy all messages from "Inbox" to "Important"
    for i = 0 to msgSet.Count-1
    	success = imap.Copy(msgSet.GetID(i),1,"Important")
    	if (success = 0) then
    		Response.Write "Message " & i & " failed: " & imap.LastErrorHtml & "<br>"
    	else
    		Response.Write "Copied message " & i & "<br>"
    	end if
    next

	imap.Logout
	imap.Disconnect
	
end if

%>
</body>
</html>