BZIP2 / AES Encrypt Strings

Download Chilkat Crypt ActiveX

This ASP script shows how to BZIP2 and AES encrypt strings

<html>
<head>
<title>BZip2 Compress and AES Encrypt Strings in ASP</title>
</head>
<body>
<%
' ASP script to Bzip2/Compress Strings
set crypt = Server.CreateObject("Chilkat.Crypt2")

' Any value passed to UnlockComponent begins the 30-day trial.
unlocked = crypt.UnlockComponent("30-day trial code")
if unlocked then

	' Note: Encrypted data is padded to a multiple of 16 bytes.
	crypt.CryptAlgorithm = "aes"
	' The key length can be 128, 192, or 256
	crypt.KeyLength = 128

	' Set the password.
	crypt.SecretKey = crypt.GenerateSecretKey("myPassword")
	
	' Indicate that we want BZip2 compression applied before encrypting.
	crypt.CompressionAlgorithm = "BZIP2"
	
	s = ""
	for i = 1 to 500
		s = s & "Compress and encrypt this text<br>"
	next
	
	zippedData = crypt.CompressString(s)

	' Return the compressed/encrypted data as a URL-encoded string.
	crypt.EncodingMode = "url"
	Response.Write "<br><br><b>URL-encoded Encrypted String:</b><br>"
	Response.Write crypt.EncryptBytesENC(zippedData)
		
	' Return the compressed/encrypted data as a base64-encoded string.
	crypt.EncodingMode = "base64"
	Response.Write "<br><br><b>Base64 Encrypted String:</b><br>"
	Response.Write crypt.EncryptBytesENC(zippedData)
		
	' Return the compressed/encrypted data as a hex-encoded string.
	crypt.EncodingMode = "hex"
	Response.Write "<br><br><b>Hexidecimalized Encrypted String:</b><br>"
	encryptedStr = crypt.EncryptBytesENC(zippedData)
	Response.Write encryptedStr
	
	' Decrypt/uncompress the string.
	Response.Write "<br><br><b>Decrypted:</b><br>"
	zippedData2 = crypt.DecryptBytesENC(encryptedStr)
	Response.Write crypt.InflateString(zippedData2)
		
else
	Response.Write "Crypt object is not unlocked!"
end if


%>
</body>
</html>